/* REXX - DUMPVAR: Show ISPF variable in EBCDIC and HEX in browse.    */
/*      Syntax:  TSO DUMPVAR  varname columns  (operands are optional)*/
/*        varname is the name of the variable to dump (default:ZPLEX) */
/*        columns is the number of 4 byte columns per line (def: 4)   */
/*--------------------------------------------------------------------*/
/* Author:Doug Nadel - nadel@us.ibm.com                               */
/* (c) Copyright IBM Corp., 1999.    All rights reserved.             */
/*--------------------------------------------------------------------*/
Parse Arg invar columns .
Parse Upper Value invar 'ZPLEX' With invar .
Parse Value columns 5 With columns .
wide=4*columns
Address ispexec 'VGET ('invar',ZAPPLID)'
Interpret 'variable = 'invar
p=c2x(variable)
Do queued()
  Pull
End
Queue 'Length of 'invar' in appl id "'zapplid'" is 'length(variable)
Queue left('- 'userid()' - 'date("S")' - 'time()' ',80,'-')
Do a=1 to 1+length(variable) by wide
  line=right('+'a-1,5)' '
  Do b=0 to wide*2-1 by 8
    line=line||substr(p,(a-1)*2+b+1,8)' '
  End
  line=line'+ 'substr(variable,a,wide)' +'
  Queue line
End
'ALLOC F($TEMP) REU NEW DEL DSO(PS) SP(1,1) TRACK RECFM(V B) LRECL(132)'
'EXECIO 'queued()' DISKW $TEMP (FINIS'
Address ispexec
'LMINIT DATAID(BBB) DDNAME($TEMP)'
'BROWSE DATAID('bbb')'
'LMFREE DATAID('bbb')'
Address tso 'FREE F($TEMP)'